Your own scripts, no server to run

/// A VAT summary for 30 days, as a PDF, sent by email.
import { byEntity } from "ugla/reports/vat/main";

const string RECIPIENT = "finance@example.test";
const int ARCHIVE = 169;
const string ZONE = "Europe/Kyiv";

export bool main(date asOf) {
    date to = today(zoneOf(ZONE)) ?? asOf;
    date from = plusDays(to, -30) ?? to;
    string period = text(from) + " to " + text(to);

    // Each legal entity pays VAT on its own:
    // the report clamps every one before the total.
    var rows = byEntity(from, to, null, null, null);

    string pdf = renderPDF(
        "<h1>VAT summary</h1><p>" + period + "</p>" + table(rows),
        "VAT summary"
    );
    string file = "vat-summary-" + text(to) + ".pdf";

    // Filed first, sent second: if the mail fails, the file exists.
    diskWriteBytes(ARCHIVE, file, pdf);

    return sendEmailWithFile(
        RECIPIENT,
        "VAT summary " + period,
        "<p>The VAT summary is attached.</p>",
        file,
        pdf
    );
}

string table(List<{
    entity: string, entityID: int?, entityHref: string,
    currency: string, obligations: decimal, credit: decimal,
    toPay: decimal, creditReserve: decimal
}> rows) {
    string body = "";

    for (r in rows) {
        body = body + "<tr><td>" + r.entity + "</td><td>"
            + text(round(r.toPay, 2)) + "</td><td>" + r.currency
            + "</td></tr>";
    }

    return "<table><tr><th>Entity</th><th>To pay</th><th></th></tr>"
        + body + "</table>";
}

/// A Disk folder for every legal entity, then a notification.
import { Entity } from "ugla/models/restaurants";
import { DiskDirectory } from "ugla/models/general";

[Notifies("entity-folders", "Entity folders", "")]
export int main(date asOf) {
    string day = text(today(zoneOf("Europe/Kyiv")) ?? asOf);
    int made = 0;

    // Reading: rows arrive as records, every column checked
    // against the live schema when the script compiles.
    var entities = from x in Entity
        where x.exist == true
        select { name: x.name };

    for (e in entities) {
        // Writing: a new row is a handle until save() stores it.
        var folder = DiskDirectory.create();

        folder.name = e.name + " " + day;
        folder.save();
        made++;
    }

    sendNotification(
        [1],
        "Entity folders",
        text(made) + " folders made for " + day + ".",
        "entity-folders"
    );

    return made;
}